Re: errorlevels

[HHullen_bEi_TECHNIKERSCHULE.bs.ni.schule.de (Helmut Hullen)]

Hallo, Peter,

Du meintest am 04.03.99 zum Thema errorlevels:

>                  Wie kann man erfahren, welchen errorlevel ein
> bestimmtes Programm zurueckgibt. Beim Schreiben anspruchsvollerer
> Batch-Dateien ist das ja noetig.

Unter DOS tut es die folgende Batch-Datei:

---------------- errlev.bat ---------------------
_bEi_echo off
REM Batch von John Evans
::rem Errorlevel von beliebigen DOS-Programmen bestimmen
  echo.
  if [%1] == [] goto end
  %1 %2 %3 %4 %5 %6 %7 %8 %9
  for %%x in (0 1 2) do if errorlevel %%x00 set el=%%x
  if not %el%==2 goto not200
  for %%x in (0 1 2 3 4 5) do if errorlevel %el%%%x0 set el=%el%%%x
  if not %el%==25 goto not250
  for %%x in (0 1 2 3 4 5) do if errorlevel %el%%%x set el=%el%%%x
goto done
:not200
  for %%x in (0 1 2 3 4 5 6 7 8 9) do if errorlevel %el%%%x0 set el=%el%%%x
:not250
  for %%x in (0 1 2 3 4 5 6 7 8 9) do if errorlevel %el%%%x set el=%el%%%x
:done
  echo.
  echo Getestet:    %1 %2 %3 %4 %5 %6 %7 %8 %9
  echo Errorlevel:  %el%
  set el=
:end

------------------- Ende errlev.bat ---------------------

Aufruf: errlev <Programmname> [Optionen]

Viele Gruesse!
Helmut